查看: 10184|回复: 7
收起左侧

[求助] 百度不到的情况.是不是病毒?

[复制链接]
liouwei388
发表于 2014-9-26 11:05:16 | 显示全部楼层 |阅读模式
本帖最后由 liouwei388 于 2014-9-26 11:12 编辑

windows8.1开机.过了开机logo在将要显示桌面的时候,屏幕左上角出现lodging system 停顿两秒钟后,进入桌面

系统是TGY_Win 8.1 Up2x64 Ent+Office 2013 SP1_V17246_UEFI      固态硬盘UEFI安装采用以下批处理

@echo off
:::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Set this flag to 1 for installing osppsvc hook
:::::::::::::::::::::::::::::::::::::::::::::::::::::::
set OsppHook=1
:::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Adjust these settings for your use
:::::::::::::::::::::::::::::::::::::::::::::::::::::::
set KMS_Emulation=1
set KMS_ActivationInterval=120
set KMS_RenewalInterval=10080
set Windows=Random
set Office2010=Random
set Office2013=Random

%windir%\system32\reg.exe query "HKU\S-1-5-19" >nul 2>&1 || (
echo      -------
echo  *** WARNING ***
echo      -------
echo.
echo.
echo ADMINISTRATOR PRIVILEGES NOT DETECTED
echo ____________________________________________________________________________
echo.
echo This script require administrator privileges.
echo.
echo To do so, right click on this script and select 'Run as administrator'
echo.
echo.
echo.
echo Press any key to exit...
pause >nul
goto :eof
)
title SppExtComObjPatcher
setlocal enableextensions
setlocal EnableDelayedExpansion
cd /d "%~dp0"
set xOS=Win32
reg query "hklm\software\microsoft\Windows NT\currentversion" /v buildlabex | find /i "amd64" >nul 2>&1 && set xOS=x64
wmic path OfficeSoftwareProtectionService get version >nul 2>&1 || set OsppHook=0

for /f "tokens=6 delims=[]. " %%G in ('ver') do set winbuild=%%G
if %winbuild% GEQ 9200 (
    set OSType=Win8
) else if %winbuild% GEQ 7600 (
    set OSType=Win7
) else (
    goto :UnsupportedVersion
)
echo.
echo Microsoft (R) Windows Software Licensing.
echo Copyright (C) Microsoft Corporation. All rights reserved.
echo =========================================================
echo.
IF EXIST "%SystemRoot%\system32\SppExtComObjPatcher.exe" goto :uninst

:inst
choice /C YN /N /M "SppExtComObjPatcher will be installed on your computer. Continue? [y/n]: "
echo.
IF ERRORLEVEL 2 exit
IF ERRORLEVEL 1 goto :run1
:run1
call :StopService sppsvc
if %OsppHook% NEQ 0 call :StopService osppsvc
echo.
echo Copying Files...
copy /y "%xOS%\SppExtComObjPatcher.exe" "%SystemRoot%\system32" >nul 2>&1 && echo status: OK
IF ERRORLEVEL 1 echo status: Error
copy /y "%xOS%\SppExtComObjHook.dll" "%SystemRoot%\system32" >nul 2>&1 && echo status: OK
IF ERRORLEVEL 1 echo status: Error
echo.
echo Creating Registry Entries...
if %OSType% EQU Win8 (
    echo Creating Registry Entry for SppExtComObj.exe of Windows 8/8.1
    call :CreateIFEOEntry "SppExtComObj.exe"
)
if %OSType% EQU Win7 (
    echo Creating Registry Entry for sppsvc.exe of Windows 7
    call :CreateIFEOEntry "sppsvc.exe"
)
if %OsppHook% NEQ 0 (
    echo Creating Registry Entry for osppsvc.exe of Office 2010/2013
    call :CreateIFEOEntry "osppsvc.exe"
)
goto :end

:uninst
choice /C YN /N /M "SppExtComObjPatcher will be removed from your computer. Continue? [y/n]: "
echo.
IF ERRORLEVEL 2 exit
IF ERRORLEVEL 1 goto :run2
:run2
call :StopService2 sppsvc
if %OsppHook% NEQ 0 call :StopService2 osppsvc
echo.
echo Removing Installed Files...
if exist "%SystemRoot%\system32\SppExtComObjPatcher.exe" (
        echo SppExtComObjPatcher.exe Found. Removing...
        del /f /q "%SystemRoot%\system32\SppExtComObjPatcher.exe"
)
if exist "%SystemRoot%\system32\SppExtComObjHook.dll" (
        echo SppExtComObjHook.dll Found. Removing...
        del /f /q "%SystemRoot%\system32\SppExtComObjHook.dll"
)
echo.
echo Removing Registry Entries...
if %OSType% EQU Win8 (
    echo Removing Registry Entry for SppExtComObj.exe of Windows 8/8.1
    call :RemoveIFEOEntry "SppExtComObj.exe"
)
if %OSType% EQU Win7 (
    echo Removing Registry Entry for sppsvc.exe of Windows 7
    call :RemoveIFEOEntry "sppsvc.exe"
)
if %OsppHook% NEQ 0 (
    echo Removing Registry Entry for osppsvc.exe of Office 2010/2013
    call :RemoveIFEOEntry "osppsvc.exe"
)
schtasks /delete /f /tn "\Microsoft\Windows\SoftwareProtectionPlatform\SvcTrigger" >nul 2>&1
goto :end

:CreateIFEOEntry
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "Debugger" /t REG_SZ /d "SppExtComObjPatcher.exe" >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "KMS_Emulation" /t REG_DWORD /d %KMS_Emulation% >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "KMS_ActivationInterval" /t REG_DWORD /d %KMS_ActivationInterval% >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "KMS_RenewalInterval" /t REG_DWORD /d %KMS_RenewalInterval% >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "Office2013" /t REG_SZ /d "%Office2013%" >nul 2>&1
if %~1 NEQ osppsvc.exe (
    reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "Windows" /t REG_SZ /d "%Windows%" >nul 2>&1
)
if %~1 EQU osppsvc.exe (
    reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "Office2010" /t REG_SZ /d "%Office2010%" >nul 2>&1
)
goto :EOF

:RemoveIFEOEntry
if %~1 NEQ osppsvc.exe (
    reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f >nul 2>&1
)
if %~1 EQU osppsvc.exe (
    reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "Debugger" >nul 2>&1
    reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "KMS_Emulation" >nul 2>&1
    reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "KMS_ActivationInterval" >nul 2>&1
    reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "KMS_RenewalInterval" >nul 2>&1
    reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "Office2010" >nul 2>&1
    reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\%~1" /f /v "Office2013" >nul 2>&1
)
goto :EOF

:StopService
sc query %1 | find /i "STOPPED" >nul 2>&1
if %ERRORLEVEL% NEQ 0 net stop %1 /y >nul 2>&1
sc query %1 | find /i "STOPPED" >nul 2>&1
if %ERRORLEVEL% NEQ 0 sc stop %1 >nul 2>&1
goto :EOF

:StopService2
sc query %1 | find /i "RUNNING" >nul 2>&1
if %ERRORLEVEL% EQU 0 net stop %1 /y >nul 2>&1
sc query %1 | find /i "RUNNING" >nul 2>&1
if %ERRORLEVEL% EQU 0 sc stop %1 >nul 2>&1
goto :EOF

:UnsupportedVersion
echo ==== ERROR ====
echo Unsupported OS version Detected.
echo This project is only supported for Windows 7/8/8.1
echo.
echo Press any key to exit...
pause >nul
exit

:end
echo.
echo Done.
echo Press any key to exit...
pause >nul
exit

引导的SppExtComObjPatcher.exe激活.是不是跟激活有关系?
mz123456
发表于 2014-9-26 15:27:06 | 显示全部楼层
1.附上系统配置资料,硬盘品牌容量,系统是原版还是Ghost?
2.没有理解你说的问题,电脑故障了吗?
liouwei388
 楼主| 发表于 2014-9-26 15:38:08 | 显示全部楼层
本帖最后由 liouwei388 于 2014-9-26 15:43 编辑

电脑配置
liouwei388
 楼主| 发表于 2014-9-26 15:42:13 | 显示全部楼层
mz123456 发表于 2014-9-26 15:27
1.附上系统配置资料,硬盘品牌容量,系统是原版还是Ghost?
2.没有理解你说的问题,电脑故障了吗?

本帖最后由 liouwei388 于 2014-9-26 15:41 编辑


电脑配置CPU 英特尔E3  1230V3  内存金士顿4G×2   硬盘金士顿固态120G+西数500G器械   


没有明显感觉出有什么问题.就是开机的时候突然就出现了那些英文lodging system.是不是有类似的病毒啊?
mz123456
发表于 2014-9-26 15:46:08 | 显示全部楼层
liouwei388 发表于 2014-9-26 15:42
本帖最后由 liouwei388 于 2014-9-26 15:41 编辑

没有影响,只是系统加载,系统用一段时间之后或多或少都会有一些小问题,不影响你使用就好了
liouwei388
 楼主| 发表于 2014-9-26 15:51:57 | 显示全部楼层
mz123456 发表于 2014-9-26 15:46
没有影响,只是系统加载,系统用一段时间之后或多或少都会有一些小问题,不影响你使用就好了

昨天刚刚做的系统.以前别的系统从来没有过.再说了UEFI安装+固态硬盘过了开机logo秒进桌面从没有在那停顿过
zzhh5511
发表于 2014-9-29 00:37:26 来自手机 | 显示全部楼层
是不是使用了分区助手后引起的?
cocoleiray
发表于 2017-7-4 22:55:16 | 显示全部楼层
SppExtComObjHook.dll
您需要登录后才可以回帖 登录 | 快速注册

本版积分规则

手机版|杀毒软件|软件论坛|优惠券| 卡饭论坛

Copyright © KaFan  KaFan.cn All Rights Reserved.

Powered by Discuz! X3.3( 苏ICP备07004770号 ) GMT+8, 2017-9-20 13:35 , Processed in 0.099799 second(s), 5 queries , MemCache On.

快速回复 返回顶部 返回列表