用批处理设置IP

liumz1963

由于特殊原因，要经常设置不同的IP地址，所以想请高手指导：
一、设置一个静态地址;二设置一个动态地址。

txt475

@echo off
rem //设置变量
set Nic="本地连接"
rem //可以根据你的需要更改,   
::--------------------------97地址----------------------------
set Addr97=133.2.13.32
set Mask97=255.255.255.128
set Gway97=133.2.13.1
set Dns97=202.103.24.68
::-------------------------外网地址----------------------------
set AddrOut=10.36.121.32
set MaskOut=255.255.255.128
set GwayOut=10.36.121.1
set DnsOut=202.103.24.68
rem //以上依次为IP地址、子网掩码、网关、首选DNS、备用DNS   
echo     1 设置为97   
echo     2 设置为外网
echo     3 退出   
echo －－－请选择项目后回车   
set /p answer=   
if %answer%==1 goto 1   
if %answer%==2 goto 2   
if %answer%==3 goto 3   
:1   
echo 97地址:        %Addr97%
echo 97掩码:        %Mask97%
echo 97网关:        %Gway97%
echo 97 DNS:        %Dns97%
echo 正在进行IP地址设置，设置完成将自动退出，请稍等...
netsh interface ipv4 set address name=%Nic% source=static addr=%Addr97% mask=%Mask97% gateway=%Gway97% gwmetric=0 >nul  
netsh interface ipv4 set dns name=%Nic% source=static addr=%Dns97% register=PRIMARY >nul   
:: echo 备用 DNS = %Dns2%   
:: netsh interface ipv4 add dns name=%Nic% addr=%Dns2% index=2 >nul   
goto end   
:2   
echo 外网地址:        %AddrOut%
echo 外网掩码:        %MaskOut%
echo 外网网关:        %GwayOut%
echo 外网 DNS：        %DnsOut%
echo 正在进行IP地址设置，设置完成将自动退出，请稍等...
netsh interface ipv4 set address name=%Nic% source=static addr=%AddrOut% mask=%MaskOut% gateway=%GwayOut% gwmetric=0 >nul   
netsh interface ipv4 set dns name=%Nic% source=static addr=%DnsOut% register=PRIMARY >nul   
:: echo 备用 DNS = %Dns2%   
:: netsh interface ipv4 add dns name=%Nic% addr=%Dns2% index=2 >nul   
goto end  
:3   
goto end
---------------------------设动态IP-------------------------
:: 动态IP设置
:: echo 正在进行动态IP设置，请稍等...   
:: echo. IP 地址正在从DHCP自动获取...   
:: netsh interface ip set address "本地连接" dhcp   
:: echo. DNS地址正在从DHCP自动获取...   
:: netsh interface ip set dns "本地连接" dhcp  
:end
echo 设置完成！退出...
exit

liumz1963

txt475 发表于 2012-9-20 08:44
@echo off
rem //设置变量
set Nic="本地连接"

谢谢你的帮助。