批处理IE缓存提取器

xp163

其实代码很简单，只是出了点力进行调试而已，我连reg query都用不好、文件扩展名不知道用变量提取，可见水平之低，所以大家多提改进意见啦！
   如果你修改过Temporary Internet Files，请改一下代码开始中的iepath变量。代码如下： 复制内容到剪贴板
代码:

@echo off
color 0a
mode con lines=26 cols=56
rem 此处进行iepath的预定义。
rem iepath为IE缓存的路径，下面是系统默认值，可根据需要修改
rem 我个人设置为了 iepath="E:\临时文件\Temporary Internet Files"
set iepath="%userprofile%\Local Settings\Temporary Internet Files"
set root=%iepath:~1,2%
:main
title [IE缓存文件提取工具]-For verybat
echo.
echo   ======================================================
echo                 ** IE缓存文件提取工具 **
echo    本工具用于去除系统限制，提取IE缓存中的任意文件
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
echo   (1) 打开IE缓存(默认)
echo     ==直接去除系统限制，自己查找所需文件==
echo   (2) 清理IE缓存
echo     ==上网时间久了，清理缓存会节省不少硬盘空间==
echo   (3) 提取IE缓存中的flv文件
echo     ==自动搜索缓存中的flv文件并移动到.flv目录==
echo   (4) 提取IE缓存中的swf文件
echo     ==自动搜索缓存中的swf文件并移动到.swf目录==
echo   (5) 自定义提取文件
echo     ==自己设定搜索文件类型，并移动到相应目录==
echo   (6) 查看说明
echo     ==想了解更多，就看看这个吧==
echo   (q) 退出
echo.
set CHS=1
set /P CHS= 请选择一个项目，回车继续!
echo.
if /I "%CHS%"=="1" goto :openie
if /I "%CHS%"=="2" goto :delie
      
if /I "%CHS%"=="3" set exts=flv & goto :ext
            
if /I "%CHS%"=="4" set exts=swf &goto :ext
            
if /I "%CHS%"=="5" goto :extset
      
if /I "%CHS%"=="6"   goto :readme
      
if /I "%CHS%"=="q" goto :end
echo ~_~不会吧，这都选错？！请回车后重试！
echo.
pause >nul
cls
goto main
:openie
title [打开IE缓存]
echo.
echo 正在打开缓存，请稍候……
%root%
cd %iepath%
ATTRIB . -S -H -R -A /S /D >nul 2>nul
ATTRIB * -S -H -R -A /S /D >nul 2>nul
start .
cls
echo 请查看IE缓存！
goto main
:delie
title [清理IE缓存]
echo.
echo 正在清理缓存，请稍候……
del /f /s /q %iepath%\Content.IE5\*.* >nul 2>nul
del /f /s /q %iepath%\Content.IE5\* >nul 2>nul
rd %iepath% /s /q
cls
echo IE缓存清理完毕！
GOTO main
:extset
echo.
set /p exts= 请输入一种你想提取的文件的扩展名，如GIF：
if "%exts%"=="" echo 扩展名不能为空，请重设！ &goto extset
:ext
echo.
title [提取%exts%文件]
echo 正在提取%exts%文件，请稍候……
%root%
cd %iepath%
ATTRIB . -S -H -R -A /S /D >nul 2>nul
ATTRIB * -S -H -R -A /S /D >nul 2>nul
if not exist %root%\.%exts% md %root%\.%exts%
for /r . %%i in (*.%exts%) do move /Y "%%i" %root%\.%exts%
rd %root%\.%exts% >nul
cls
IF EXIST %root%\.%exts% (
    echo %exts%文件已经提取，并放在%root%\.%exts%目录下！
    start %root%\.%exts%
) ELSE (
    echo %exts%文件没有发现！你可以尝试提取其他格式文件。
)
GOTO main
:readme
cls
title [使 用 说 明]
color ce
echo             [使 用 说 明]-By maztgo
echo.
echo    我们浏览网页时所产生的文件都会存放进一个叫做
echo Temporary Internet Files的文件夹，这就是IE缓存。
echo 在这个文件夹里我们就能够轻松获得无法下载的文件！
echo 然而，出于安全性考虑，这个文件夹是由系统管理的，
echo 我们不能打开、查看、复制和移动文件，这个工具就是
echo 用来解除这些限制的，现在你就随心所欲的获得网页里
echo 使用过的flv,swf,mp3,wmv,rm,gif,jpg,bmp,png,js吧！
echo.
echo    在开始写这个工具之前我特地上网查了相关软件，
echo 结果找到了三个。但是都不合适："废客IE资源提取器"
echo 不能自定义缓存路径；"彩虹IE缓存探宝"稳定性不佳，
echo 关闭时会弹出广告并卡死；"缓存拾贝"功能较多，但是
echo 搜索时容易出错，操作有些繁琐，不能移动缓存的文件。
echo 最终还是决定用批处理自己写一个，虽然界面丑了点，
echo 但是功能专业、使用方便，程序大小还不到5K。
echo.
echo    建议在第一次使用时先清理IE缓存，然后浏览网页，
echo 这样提取浏览网页产生的缓存文件时会比较快一些。
echo.
echo    我的邮箱是 maztgo@gmail.com，有疑问可以联系。
echo.
echo     按任意键返回主界面……
pause >nul
cls
goto :main
:end
exit

rem 所有版权，属于maztgo，如有修改，版权不究。
rem 程序完成时间：2007年11月15日
扩展知识：
   常见的网页中的文件格式：flv swf mp3 rm asf asx smi wma mid ape ra jpg jpeg gif tif tiff png bmp ico ani cur rar zip htm html shtml xml asp aspx php php3 txt css cdf js vbs cgi ini ……
history：

i5151

看来楼主对批处理感兴趣。