批命令关闭vmware

power562

tasklist | findstr /i "vmware-tray.exe" > nul &&  taskkill /f /t /im “vmware-tray.exe”
可以加个判断，若vmware-tray.exe进程存在，则 kill 掉

power562

我把我的批处理分享一下，适用于VM7.0以上版本。把下边的内容复制进txt文档中，然后把txt后缀改成bat就OK了。如果是win7用户，执行的时候在bat文件上按右键，选择“以管理员身份运行”，否则会执行失败。

@echo off
color 1a

:main
cls
echo.
echo 1  启动VMware服务
echo.
echo 2  停止VMware服务
echo.
echo 0  直接退出
echo.
set /p num=请输入（1/2/0）然后回车:
if /i '%num%'=='1' GOTO start
if /i '%num%'=='2' GOTO stop
if /i '%num%'=='0' exit
cls
echo 输入错误：请重新输入
echo.
pause
GOTO main

:start
cls&&echo 正在启动VMware服务，请稍候...
echo.
(net start | find /i "VMware Authorization Service" > nul && echo "VMware Authorization Service 服务已经启动") || net start VMAuthdService
(net start | find /i "VMware DHCP Service" > nul && echo "VMware DHCP Service 服务已经启动") || net start VMnetDHCP
(net start | find /i "VMware NAT Service" > nul && echo "VMware NAT Service 服务已经启动") || net start "VMware NAT Service"
(net start | find /i "VMware USB Arbitration Service" > nul && echo "VMware USB Arbitration Service 服务已经启动") || net start VMUSBArbService
REM (net start | find /i "VMware Workstation Server" > nul && echo "VMware Workstation Server 服务已经启动") || net start VMwareHostd
echo.
GOTO lo

:stop
cls&&echo 正在停止VMware服务，请稍候...
echo.
(tasklist | findstr /i "vmware-tray.exe" > nul && taskkill /f /t /im "vmware-tray.exe") || echo "vmware-tray.exe 进程不存在"
(net start | find /i "VMware DHCP Service" > nul && net stop VMnetDHCP) || echo "VMware DHCP Service 服务已经停止"
(net start | find /i "VMware NAT Service" > nul && net stop "VMware NAT Service") || echo "VMware NAT Service 服务已经停止"
(net start | find /i "VMware USB Arbitration Service" > nul && net stop VMUSBArbService) || echo "VMware USB Arbitration Service 服务已经停止"
REM (net start | find /i "VMware Workstation Server" > nul && net stop VMwareHostd) || echo "VMware Workstation Server 服务已经停止"
(net start | find /i "VMware Authorization Service" > nul && net stop VMAuthdService) || echo "VMware Authorization Service 服务已经停止"
echo.
GOTO lo

:lo
echo.
SET /p yn=是否返回继续操作 : [y/n]
IF %yn% == y GOTO main
exit