自动关机如何实现?

JohnChu

如何实现自动关机?
我要每天早上6点关机
(XP系统)
请尽管详细一点，谢谢
问题解决，谢谢大家，谢谢所有回帖的童鞋们

ADSLgg

很多软件都有这功能的
酷狗7就有这功能了
装机时的一些小工具也有

JohnChu

我需要的是那种加在自启动项里的脚本

fwe

设置每天自动定时关机批处理

@ECHO off
TITLE  greaterthanme-实现定时关机、注销、重启、锁定等功能。

:start
CLS
COLOR 1f
rem 使用COLOR命令对控制台输出颜色进行更改
MODE con: COLS=41 LINES=18
rem MODE语句为设定窗体的宽和高
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
ECHO %date% %tm1%点%tm2%分%tm3%秒
ECHO =========================================
ECHO 请选择要进行的操作，然后按回车
ECHO ———————————————
ECHO.
ECHO 1. 定时关机
ECHO 2. 倒计时关机
ECHO 3. 删除定时关机任务
ECHO 4. 查看任务状态
ECHO 5. 刷新当前时间
ECHO 6. 重新启动
ECHO 7. 锁定计算机
ECHO 8. 注销
ECHO 9. 退出
ECHO.

:cho
SET Choice=
SET /P Choice=选择:
rem 设定变量"Choice"为用户输入的字符
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 如果输入大于1位,取第1位,比如输入132,则返回值为1
ECHO.
IF /I "%Choice%"=="1" GOTO SetHour
IF /I "%Choice%"=="2" GOTO outtime
IF /I "%Choice%"=="3" GOTO delAt
IF /I "%Choice%"=="4" GOTO view
IF /I "%Choice%"=="5" GOTO start
IF /I "%Choice%"=="6" GOTO restart
IF /I "%Choice%"=="7" GOTO lock
IF /I "%Choice%"=="8" GOTO logoff
IF /I "%Choice%"=="9" GOTO end
rem 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号
rem 注意,IF语句需要双等于号
rem 如果输入的字符不是以上数字,将返回重新输入
ECHO 选择无效，请重新输入
ECHO.
GOTO cho

:SetHour
CLS
ECHO.
SET ask=
SET /p ask=是否设定为每天执行关机命令(y/n):
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="y" GOTO yes
IF /I "%ask%"=="n" GOTO no
GOTO SetHour

:yes
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul
rem 设定为每周的星期一至星期日,即为每天
IF NOT errorlevel 1 GOTO ok
rem 如果输入正确,就执行ok段的语句
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO yes

:no
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF NOT errorlevel 1 GOTO ok
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO no

:ok
ECHO.
SET h=%shutdowntime:~1,1%
SET ah=%shutdowntime:~0,1%
SET am=%shutdowntime:~2,2%
SET bh=%shutdowntime:~0,2%
SET bm=%shutdowntime:~3,2%
IF "%h%"==":" (
SET HM=%ah%时%am%分
) ELSE (
SET HM=%bh%时%bm%分)
rem 如果输入h:mm则HM=h时mm分,否则HM=hh时mm分
IF /I "%ask%"=="y" ECHO 系统将于每天的%HM%关闭
IF /I "%ask%"=="n" ECHO 系统将于%HM%关闭
ECHO 设定完毕! 按任意键继续...
PAUSE >nul
GOTO start

:outtime
CLS
ECHO.
ECHO 请输入倒计时秒数
ECHO ————————
ECHO (设定后要取消,单击"确定"后按Ctrl+C键两次)
SET timed=
SET /p timed=输入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 GOTO ok
ECHO %timed% 是无效的关机时间,请重新输入
ECHO.
GOTO outtime

:delAt
cls
echo.
at /del /y
echo 定时关机任务已取消,按任意键继续...
pause >nul
GOTO start

:view
MODE con: COLS=85 LINES=18
COLOR 70
ECHO.
at
ECHO 按任意键继续...
PAUSE >nul
GOTO start

:restart
shutdown -r -t 0

:lock
rundll32.exe user32.dll,LockWorkStation
goto start

:logoff
logoff

:end
exit

qrw4bhhg4

关机命令是：shutdown -s
自己在任务计划里设置一下就行了，想几点关机就设定到几点，并设定为每天运行。

laji369

用计划任务实现方式如下：
1.计算机管理——计划任务——新建

2.触发器——设置关机时间
3.操作——新建如下启动程序


其他根据需要酌情调整

fuyunqing55

4、6楼的方法都可以
如果要加入启动项的话 照4楼的做
创建一个文本文档 把4楼的复制进去 在根据提示修改数值  然后保存 最后把该文档的.txt改为.bat(好像是吧 我也记不清楚了不是请楼下纠正）  让后把该文件加入开机启动项就OK了
实在不会PM我

shshp007

下载个自动关机的小软件。、不过电源还是不能自动关。。

auhuiL

1、新建一个txt文档，并且在其中输入：“at 6:00 shutdown -s”；
2、修改“.txt”为“.bat”；
3、将文件放入开始-程序-启动。
ok

nb33020319

现在的电脑其实还有一种方法可以在BIOS中实现自动关机：进入CMOS，到电源选项（POWER Management Setup),回车进入子菜单。将RESUME by Alarm项设为ENABLED，并在DATE(OF MONTH) ALARM项中设置每月的开机日期(0表示每天，1表示每月1日，2表示每月2日。。。)，在TIME(hh:mm:ss)ALAMR中设置开机时间，最后保存，重新启动。当关闭计算机后，你的电脑将按你设定的时间自动开机。
注意：1、你的电脑主板必须有RESUME by Alarm功能才能实现自动开机。
2、要实现定时开机，必须取消开机密码。
3、主机电源要一直接通。