收藏本站 |切换到宽版 | 更换论坛皮肤
 找回密码  忘记邮箱  QQ快速登录  快速登录  快速注册

卡饭»论坛 › 软件区 › 解疑答难区 › 怎样才能使这个批处理弹出的窗口居中？谢谢
返回列表 发新帖
查看: 1522|回复: 5
收起左侧

[其他] 怎样才能使这个批处理弹出的窗口居中？谢谢

[复制链接]
yyz219
头像被屏蔽
发表于 2022-1-10 11:05:09 | 显示全部楼层 |阅读模式
本帖最后由 yyz219 于 2022-1-10 11:18 编辑

怎样才能使这个批处理弹出的窗口居中？谢谢
+++++++++++++++++++++++++++++
需要窗口居中.bat：
@echo off
Title Notepad3替換系统记事本
::界面大小，Cols为宽，Lines为高
mode con cols=45 lines=10
color 2F
pause>nul
回复

举报

cnseatech
发表于 2022-1-10 12:04:35 | 显示全部楼层
是不是要获取分辨率啊
回复

举报

yyz219
头像被屏蔽
 楼主| 发表于 2022-1-10 12:13:29 | 显示全部楼层
cnseatech 发表于 2022-1-10 12:04
是不是要获取分辨率啊

我不晓得。
回复

举报

Chatter-X
发表于 2022-1-10 12:21:22 | 显示全部楼层
【方案一】比较原始的方法，思路比较容易理解。
  1. @echo  off
  2. ::Batcher@bbs.bathome.net
  3. ::2009-03-04
  4. ::命令行窗口自动居中之批处理版@CMD@XP
  5. ::http://bbs.bathome.net/thread-3582-1-1.html

  7. setlocal enabledelayedexpansion
  8. ::指定命令行窗口字体大小（默认是8*16）
  9. set FontWidth=8
  10. set FontHeight=16
  11. ::指定命令行窗口大小（默认是80*25）
  12. set WinCol=80
  13. set WinRow=25

  15. ::ClearOldConf
  16. for /f "tokens=3 delims=" %%a in ('reg query HKEY_CURRENT_USER\Console^|findstr "_system32_cmd.exe"') do (
  17.   if "%%a" neq "" (
  18.     reg delete HKEY_CURRENT_USER\Console\%%a /va /f
  19.   )
  20. )

  22. ::SetFontSize
  23. call :Dec2Hex %FontWidth% FontWidthH
  24. call :Dec2Hex %FontHeight% FontHeightH
  25. set FontWidthH=0000%FontWidthH%
  26. set FontWidthH=%FontWidthH:~-4%
  27. reg add HKEY_CURRENT_USER\Console /v FontSize /t reg_dword /d 0x%FontHeightH%%FontWidthH% /f

  29. ::SetWinSize
  30. call :Dec2Hex %WinCol% WinColH
  31. call :Dec2Hex %WinRow% WinRowtH
  32. set WinColH=0000%WinColH%
  33. set WinColH=%WinColH:~-4%
  34. reg add HKEY_CURRENT_USER\Console /v WindowSize /t reg_dword /d 0x%WinRowtH%%WinColH% /f

  36. ::GetWinSize
  37. set /a WinWidth=WinCol*FontWidth+33
  38. set /a WinHeight=WinRow*FontHeight+45

  40. ::GetSrcSize
  41. for /f "tokens=2 delims==" %%a in ('wmic desktopmonitor get screenwidth /value') do (
  42.   set ScrWidth=%%a
  43.   goto :GetSrcHeight
  44. )
  45. :GetSrcHeight
  46. for /f "tokens=2 delims==" %%a in ('wmic desktopmonitor get screenheight /value') do (
  47.   set ScrHeight=%%a
  48.   goto :GetPosition
  49. )

  51. :GetPosition
  52. set /a PosLeft=(ScrWidth-WinWidth)/2
  53. set /a PosTop=(ScrHeight-WinHeight)/2
  54. call :Dec2Hex %PosLeft% PosLeftH
  55. call :Dec2Hex %PosTop% PosTopH
  56. set PosLeftH=0000%PosLeftH%
  57. set PosLeftH=%PosLeftH:~-4%
  58. set PosTopH=0000%PosTopH%
  59. set PosTopH=%PosTopH:~-4%
  60. reg add HKEY_CURRENT_USER\Console /v WindowPosition /t reg_dword /d 0x%PosTopH%%PosLeftH% /f
  61. start cmd
  62. goto :eof

  64. :Dec2Hex
  65. set num=%1
  66. set str=0123456789ABCDEF
  67. set numDiv=%num%
  68. set numConn=
  69. :LoopD2H
  70. set /a numMod=numDiv%%16
  71. set numMod=!str:~%numMod%,1!
  72. set /a numDiv/=16
  73. set numConn=%numMod%%numConn%
  74. if %numDiv% equ 0 (
  75.   set %2=%numConn%
  76.   goto :eof
  77. )
  78. goto :LoopD2H
复制代码



【方案二】采用18楼pusofalse兄的方法：移位+或，可以缩短代码、提高执行效率。
  1. @echo off
  2. ::Batcher@bbs.bathome.net
  3. ::2009-03-17
  4. ::命令行窗口自动居中之批处理版@CMD@XP
  5. ::http://bbs.bathome.net/thread-3582-1-1.html

  7. setlocal enabledelayedexpansion
  8. ::指定命令行窗口字体大小（默认是8*16）
  9. set FontWidth=8
  10. set FontHeight=16
  11. ::指定命令行窗口大小（默认是80*25）
  12. set WinCol=80
  13. set WinRow=25

  15. ::SetFontSize
  16. set /a "FontSizeD=FontHeight<<16|FontWidth"
  17. call :Dec2Hex %FontSizeD% FontSizeH
  18. reg add HKEY_CURRENT_USER\Console /v FontSize /t reg_dword /d 0x%FontSizeH% /f

  20. ::SetWinSize
  21. set /a "WinSizeD=WinRow<<16|WinCol"
  22. call :Dec2Hex %WinSizeD% WinSizeH
  23. reg add HKEY_CURRENT_USER\Console /v WindowSize /t reg_dword /d 0x%WinSizeH% /f

  25. ::GetWinSize
  26. set /a WinWidth=WinCol*FontWidth+33
  27. set /a WinHeight=WinRow*FontHeight+45

  29. ::GetSrcSize
  30. for /f "tokens=2 delims==" %%a in ('wmic desktopmonitor get screenwidth /value') do (
  31.   set ScrWidth=%%a
  32.   goto :GetSrcHeight
  33. )
  34. :GetSrcHeight
  35. for /f "tokens=2 delims==" %%a in ('wmic desktopmonitor get screenheight /value') do (
  36.   set ScrHeight=%%a
  37.   goto :GetPosition
  38. )

  40. :GetPosition
  41. set /a PosLeft=(ScrWidth-WinWidth)/2
  42. set /a PosTop=(ScrHeight-WinHeight)/2
  43. echo %PosLeft% %PosTop%
  44. set /a "PosD=PosTop<<16|PosLeft"
  45. call :Dec2Hex %PosD% PosH
  46. reg add HKEY_CURRENT_USER\Console /v WindowPosition /t reg_dword /d 0x%PosH% /f
  47. start cmd
  48. goto :eof

  50. :Dec2Hex
  51. set num=%1
  52. set str=0123456789ABCDEF
  53. set numDiv=%num%
  54. set numConn=
  55. :LoopD2H
  56. set /a numMod=numDiv%%16
  57. set numMod=!str:~%numMod%,1!
  58. set /a numDiv/=16
  59. set numConn=%numMod%%numConn%
  60. if %numDiv% equ 0 (
  61.   set %2=%numConn%
  62.   goto :eof
  63. )
  64. goto :LoopD2H
复制代码


来源于：http://bbs.bathome.net/thread-3582-1-1.html

评分

参与人数 1人气 +3 收起 理由
yyz219 + 3 我需要的是仅对这个批处理的

查看全部评分

回复

举报

yyz219
头像被屏蔽
 楼主| 发表于 2022-1-10 12:31:10 | 显示全部楼层
Chatter-X 发表于 2022-1-10 12:21
【方案一】比较原始的方法，思路比较容易理解。

我试一试先。谢谢！
回复

举报

yyz219
头像被屏蔽
 楼主| 发表于 2022-1-10 12:33:57 | 显示全部楼层
Chatter-X 发表于 2022-1-10 12:21
【方案一】比较原始的方法，思路比较容易理解。

这个好像是设置整体的。

我需要的是仅仅这个批处理的
回复

举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 快速注册

本版积分规则

手机版|杀毒软件|软件论坛| 卡饭论坛

Copyright © KaFan  KaFan.cn All Rights Reserved.

Powered by Discuz! X3.4( 沪ICP备2020031077号-2 ) GMT+8, 2024-11-24 07:17 , Processed in 0.137797 second(s), 17 queries .

卡饭网所发布的一切软件、样本、工具、文章等仅限用于学习和研究，不得将上述内容用于商业或者其他非法用途，否则产生的一切后果自负，本站信息来自网络，版权争议问题与本站无关，您必须在下载后的24小时之内从您的电脑中彻底删除上述信息，如有问题请通过邮件与我们联系。

快速回复 客服 返回顶部 返回列表