自动激活 x 自动更新订阅 x 如何更优雅地使用测试版激活码

显示全部楼层 · 发表于 2026-8-14 07:48:34

顶起来。。

显示全部楼层 · 发表于 2026-8-16 09:36:49

这个要得支持一下，感谢

显示全部楼层 · 发表于 2026-8-17 20:29:43

goood！

显示全部楼层 · 发表于 2026-8-22 22:49:59

好奇怪，三台电脑系统一样，其中2台正常使用复制的bat代码安装，另一台电脑就是运行bat文件一闪而过，但是运行其他bat文件又正常，百思不得其解

显示全部楼层 · 发表于 2026-8-26 23:42:26

支持windows 26H1

[url=home.php?mod=space&uid=331734]@echo[/url] off
REM Set the current directory and start a diagnostic log
set "scriptDir=%~dp0"
cd /d "%scriptDir%"
set "logfile=%scriptDir%startup-debug.log"
>>"%logfile%" echo.
>>"%logfile%" echo ===== %date% %time% startup.bat started =====
echo [DEBUG] Script started.
echo [DEBUG] Log file: "%logfile%"
>>"%logfile%" echo [DEBUG] Current directory: %CD%
REM Step 1: Get admin rights
echo [DEBUG] Checking administrator rights...
>>"%logfile%" echo [DEBUG] Checking administrator rights...
powershell -NoProfile -Command "$identity = [Security.Principal.WindowsIdentity]::GetCurrent(); $principal = New-Object Security.Principal.WindowsPrincipal($identity); if ($principal.IsInRole([Security.Principal.WindowsBuiltInRole]::Administrator)) { exit 0 } else { exit 1 }"
set "adminCheckError=%errorlevel%"
echo [DEBUG] Administrator check exit code: %adminCheckError%
>>"%logfile%" echo [DEBUG] Administrator check exit code: %adminCheckError%
if "%adminCheckError%" == "0" goto :gotAdmin
echo [DEBUG] Requesting administrator rights...
>>"%logfile%" echo [DEBUG] Requesting administrator rights...
powershell -NoProfile -Command "Start-Process -FilePath '%ComSpec%' -ArgumentList '/d /c ""%~f0""' -Verb RunAs -WorkingDirectory '%~dp0'"
set "elevationError=%errorlevel%"
echo [DEBUG] Elevation launch exit code: %elevationError%
>>"%logfile%" echo [DEBUG] Elevation launch exit code: %elevationError%
if not "%elevationError%" == "0" (
echo [ERROR] Could not start the elevated copy. Was the UAC prompt cancelled?
>>"%logfile%" echo [ERROR] Could not start the elevated copy.
pause
)
exit /B
:gotAdmin
setlocal EnableExtensions EnableDelayedExpansion
echo [DEBUG] Administrator rights confirmed.
>>"%logfile%" echo [DEBUG] Administrator rights confirmed.
if not exist "%scriptDir%startup.exe" (
echo [ERROR] startup.exe was not found in "%scriptDir%".
>>"%logfile%" echo [ERROR] startup.exe was not found.
pause
goto :done
)
REM Step 2: Get version information from startup.exe
echo [DEBUG] Reading startup.exe version...
>>"%logfile%" echo [DEBUG] Reading startup.exe version...
for /f "usebackq delims=" %%i in (`powershell -command "& {(Get-Item '.\startup.exe').VersionInfo.ProductVersion}"`) do (
set "fullversion=%%i"
)
if not defined fullversion (
echo [ERROR] Could not read startup.exe ProductVersion.
>>"%logfile%" echo [ERROR] Could not read startup.exe ProductVersion.
pause
goto :done
)
echo [DEBUG] Product version: !fullversion!
>>"%logfile%" echo [DEBUG] Product version: !fullversion!
REM Extract just the first two segments (e.g., 21.20 from 21.20.8.505)
for /f "tokens=1,2 delims=." %%a in ("!fullversion!") do (
set "majorversion=%%a.%%b"
)
if not defined majorversion (
echo [ERROR] Could not determine the major version.
>>"%logfile%" echo [ERROR] Could not determine the major version.
pause
goto :done
)
echo Detected Kaspersky version: !majorversion!
set "registryPath=HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\KasperskyLab\AVP!majorversion!\environment"
echo [DEBUG] Registry path: !registryPath!
>>"%logfile%" echo [DEBUG] Registry path: !registryPath!
REM Step 3: Ask user to choose
:autoRenewal
echo.
echo Would you like to enable automatic license renewal?
set "renewal="
set /p renewal="Enter your choice (y/n): "
if /I "!renewal!"=="y" (
goto :editionSelection
) else if /I "!renewal!"=="n" (
goto :installation
) else (
echo Invalid choice.
goto :autoRenewal
)
:editionSelection
echo.
echo Please select Kaspersky edition:
echo 1. Standard
echo 2. Plus
echo 3. Premium
echo.
set /p edition="Enter your choice (1-3): "
if "!edition!"=="1" (
set "editionName=Kaspersky Standard"
set "licenseKey=GAJPU-UTD18-3B2JJ-62CQ2"
) else if "!edition!"=="2" (
set "editionName=Kaspersky Plus"
set "licenseKey=GE86F-9WQRM-KK5PG-1ZE2W"
) else if "!edition!"=="3" (
set "editionName=Kaspersky Premium"
set "licenseKey=5AP55-UFAT1-QUMNN-7CUDZ"
) else (
echo Invalid choice.
goto :editionSelection
)
echo.
echo Selected edition: !editionName!
echo [DEBUG] Selected edition: !editionName!
>>"%logfile%" echo [DEBUG] Selected edition: !editionName!
:installation
REM Step 4: Run "startup.exe" without self protection
echo.
echo Installing Kaspersky with self protection disabled...
echo [DEBUG] Starting "%scriptDir%startup.exe"...
>>"%logfile%" echo [DEBUG] Starting "%scriptDir%startup.exe" with /pSelfProtection=0
start "" "%scriptDir%startup.exe" /pSelfProtection=0
echo [DEBUG] start command exit code: !errorlevel!
>>"%logfile%" echo [DEBUG] start command exit code: !errorlevel!
REM Step 5: Monitor registry key and modify values during installation
echo.
echo Monitoring and updating registry values...
set /a registryWait=0
:checkRegistry
REG QUERY "!registryPath!" /v "ProductStatus" >nul 2>&1
if !errorlevel! equ 0 (
echo [DEBUG] Registry value found after !registryWait! checks.
>>"%logfile%" echo [DEBUG] Registry value found after !registryWait! checks.
echo Registry found, applying modifications...
REG ADD "!registryPath!" /v "ProductStatus" /t REG_SZ /d "" /f >nul 2>&1
echo [DEBUG] REG ADD exit code: !errorlevel!
>>"%logfile%" echo [DEBUG] REG ADD exit code: !errorlevel!
echo Registry modifications completed.
goto :setupTask
) else (
set /a registryWait+=1
echo [DEBUG] Registry value not found; retry !registryWait! in 5 seconds...
>>"%logfile%" echo [DEBUG] Registry value not found; retry !registryWait! in 5 seconds.
timeout /t 5 /nobreak >nul
goto :checkRegistry
)
:setupTask
if /I "!renewal!"=="n" (
echo [DEBUG] Automatic renewal disabled; skipping scheduled task setup.
>>"%logfile%" echo [DEBUG] Automatic renewal disabled; skipping scheduled task setup.
goto :done
)
REM Step 6: Manage scheduled task for license renewal
set /a avpWait=0
:search
REM Clear previous value
set "avp="
REM Search for avp.com under Kaspersky Lab directory
for /f "delims=" %%A in ('dir /b /s /a-d "C:\Program Files (x86)\Kaspersky Lab\avp.com" 2^>nul') do (
set "avp=%%A"
)
if not defined avp (
set /a avpWait+=1
echo [DEBUG] avp.com not found; retry !avpWait! in 5 seconds...
>>"%logfile%" echo [DEBUG] avp.com not found; retry !avpWait! in 5 seconds.
timeout /t 5 >nul
goto :search
)
echo.
echo Found avp.com at: !avp!
>>"%logfile%" echo [DEBUG] Found avp.com at: !avp!
echo Creating new license renewal task to run every 28 days...
>>"%logfile%" echo [DEBUG] Creating scheduled task.
set "taskname=Kaspersky License Renewal"
set "xmlfile=%TEMP%\task.xml"
REM Creating new license renewal task...
schtasks /create /tn "%taskname%" /tr ""!avp!" LICENSE /add !licenseKey!" /sc DAILY /mo 28 /f >nul 2>&1
set "taskCreateError=!errorlevel!"
echo [DEBUG] schtasks create exit code: !taskCreateError!
>>"%logfile%" echo [DEBUG] schtasks create exit code: !taskCreateError!
if not "!taskCreateError!"=="0" (
echo [ERROR] Could not create the scheduled task.
>>"%logfile%" echo [ERROR] Could not create the scheduled task.
pause
goto :done
)
REM Exporting the task to XML...
schtasks /query /tn "%taskname%" /xml > "%xmlfile%"
set "taskQueryError=!errorlevel!"
echo [DEBUG] schtasks query exit code: !taskQueryError!
>>"%logfile%" echo [DEBUG] schtasks query exit code: !taskQueryError!
if not "!taskQueryError!"=="0" (
echo [ERROR] Could not export the scheduled task XML.
>>"%logfile%" echo [ERROR] Could not export the scheduled task XML.
pause
goto :done
)
REM Modifying XML settings...
REM Use PowerShell to update XML
powershell -Command ^
"(Get-Content -Path '%xmlfile%') -replace '<StartWhenAvailable>false</StartWhenAvailable>', '<StartWhenAvailable>true</StartWhenAvailable>' |" ^
"ForEach-Object {$_ -replace '<DisallowStartIfOnBatteries>true</DisallowStartIfOnBatteries>', '<DisallowStartIfOnBatteries>false</DisallowStartIfOnBatteries>'} |" ^
"Set-Content -Path '%xmlfile%'" >nul 2>&1
echo [DEBUG] XML update exit code: !errorlevel!
>>"%logfile%" echo [DEBUG] XML update exit code: !errorlevel!
REM Re-importing modified task...
schtasks /delete /tn "%taskname%" /f >nul 2>&1
schtasks /create /tn "%taskname%" /xml "%xmlfile%" /f >nul 2>&1
echo [DEBUG] Scheduled task re-create exit code: !errorlevel!
>>"%logfile%" echo [DEBUG] Scheduled task re-create exit code: !errorlevel!
echo Task updated successfully.
echo.
echo Activating !editionName!...
set /a startupWait=0
:checkStartup
REM Check if avp.exe is running
tasklist | find /i "avp.exe" >nul 2>&1
if !errorlevel! neq 0 (
set /a startupWait+=1
echo [DEBUG] avp.exe is not running; retry !startupWait! in 5 seconds...
>>"%logfile%" echo [DEBUG] avp.exe is not running; retry !startupWait! in 5 seconds.
timeout /t 5 >nul 2>&1
goto :checkStartup
)
echo [DEBUG] avp.exe is running; starting scheduled task.
>>"%logfile%" echo [DEBUG] avp.exe is running; starting scheduled task.
schtasks /run /tn "%taskname%"
echo [DEBUG] schtasks run exit code: !errorlevel!
>>"%logfile%" echo [DEBUG] schtasks run exit code: !errorlevel!
echo.
echo Selected edition: !editionName!
echo Using version: !majorversion!
echo License key: %licenseKey%
:done
echo Process completed successfully.
>>"%logfile%" echo [DEBUG] Script finished.
echo [DEBUG] Finished. Press any key to close this window.
pause >nul
endlocal

复制代码

显示全部楼层 · 发表于 2026-8-29 18:44:02

感谢老哥，不过这个可以登陆账户吗，有啥影响没

显示全部楼层 · 发表于 2026-9-7 08:37:15

我叫王臻发表于 2026-8-29 18:44
感谢老哥，不过这个可以登陆账户吗，有啥影响没

试用版你登录账号干啥？最好不登免得被发现

显示全部楼层 · 发表于 2026-9-7 20:47:29

指尖D沙漏发表于 2026-8-22 22:49
好奇怪，三台电脑系统一样，其中2台正常使用复制的bat代码安装，另一台电脑就是运行bat文件一闪而过，但是 ...

是不是动服务或优化过后装的？

显示全部楼层 · 发表于 2026-9-8 00:05:02

sdtzsf 发表于 2026-9-7 20:47
是不是动服务或优化过后装的？

没有处理过

显示全部楼层 · 发表于 2026-9-17 17:52:27

一直卡在这界面，安装失败

[卡巴教程] 自动激活 x 自动更新订阅 x 如何更优雅地使用测试版激活码