vm6.5太强悍了有没有达人汉化下

显示全部楼层 · 发表于 2008-10-6 23:05:43

我把那个tray的开机启动项也删了。

显示全部楼层 · 发表于 2008-10-6 23:14:52

我是自己手动修改的开机启动项,你的事批处理里禁止的吗?是的话分享下你的批处理呀[:27:]

显示全部楼层 · 发表于 2008-10-6 23:24:57

我也是手动删除的，感觉没什么用处。

显示全部楼层 · 发表于 2008-10-6 23:27:18

是啊a兄有没有装sd啊,除正式版了,想装个正式的,,卸载的sd的话是不是先要退出影子还是可以直接删除呢?

显示全部楼层 · 发表于 2008-10-6 23:31:00

卸载sd先要退出影子才可以删除哦。

显示全部楼层 · 发表于 2008-10-6 23:32:54

ok多谢了..这个sd够麻烦,又不能覆盖,这次的更新了nero正是想要的..

显示全部楼层 · 发表于 2008-10-7 00:23:38

改完的批处理：

@echo off
title VMware服务控制程序
color 5f
cls
echo.
echo.
echo A——设置VMware服务启动方式为自动
echo.
echo S——启动VMware服务
echo.
echo M——设置VMware服务启动方式为手动
echo.
echo T——停止VMware服务
echo.
echo K——暂时关闭VMWare的托盘图标
echo.
echo D——禁止VMWare自动启动托盘图标程序
echo.
echo 　　　　　　　　　　　　　　小宋制作
echo 　　　欢迎访问卡饭论坛：bbs.kafan.cn
echo.
SET t=
SET /P t=请选择（A/S/M/T/K/D）:
IF /I '%t:~0,1%'=='a' GOTO auto
IF /I '%t:~0,1%'=='s' GOTO start
IF /I '%t:~0,1%'=='m' GOTO demand
IF /I '%t:~0,1%'=='t' GOTO stop
IF /I '%t:~0,1%'=='k' GOTO killtray
IF /I '%t:~0,1%'=='d' GOTO deltray
exit
:auto
cls&&echo 正在修改服务启动方式为自动，请稍候...
sc config VMAuthdService start= auto>nul
sc config VMnetDHCP start= auto>nul
sc config "VMware NAT Service" start= auto>nul
echo 全部VMware服务已经更改为自动。
goto finish
:start
cls&&echo 正在启动服务，请稍候...
net start VMAuthdService>nul
net start VMnetDHCP>nul
net start "VMware NAT Service">nul
echo VMware服务启动完毕。
goto finish
:stop
cls&&echo 正在停止服务，请稍候...
net stop VMAuthdService>nul
net stop VMnetDHCP>nul
net stop "VMware NAT Service">nul
echo VMware服务已经全部停止。
goto finish
:demand
cls&&echo 正在修改服务启动方式为手动，请稍候...
sc config VMAuthdService start= demand>nul
sc config VMnetDHCP start= demand>nul
sc config "VMware NAT Service" start= demand>nul
echo 全部VMware服务已经更改为手动启动。
goto finish
:killtray
taskkill /f /im:"vmware-tray.exe"
echo 已经成功的关闭了VMWare的托盘图标。
echo 如需重新打开，请手动运行或重启计算机。
goto finish
:deltray
echo 该操作不可恢复，确定继续吗？
echo 按任意键继续，用鼠标点击右上角的“X”取消本操作。&pause>nul
reg delete HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /v vmware-tray /f
echo 成功的删除了VMWare的托盘图标启动项。
goto finish
:finish
echo.&&echo.&&echo.
echo 操作成功，按任意键退出。
echo.
echo 　　　　　　　　　　　　　　By 小宋
pause>nul&&exit

复制代码

显示全部楼层 · 发表于 2008-10-7 00:27:48

太感谢了.宋斑..好东西啊..立马收藏

显示全部楼层 · 发表于 2008-10-7 00:34:37

谢谢宋版，copy收藏。

显示全部楼层 · 发表于 2008-10-7 11:04:50

完全汉化的话，汉化量很大很大……

不是一般人可以想象……

[已解决] vm6.5太强悍了有没有达人汉化下

回复 10楼肉包子的帖子

回复 11楼 alankoh 的帖子

回复 12楼肉包子的帖子

回复 13楼 alankoh 的帖子

回复 14楼肉包子的帖子

回复 15楼 alankoh 的帖子

回复 17楼 SONGBOWEN 的帖子