vmware 虚拟机 的服务项

zzt323

我将vm的四项服务全改成手动启动，会影响vm装系统和运行吗？
如果有影响，那些可以手动，请说明
谢谢各位，顺便问一下，linux 那个版本比较好 ？

zzt323

nobody 回答？我顶

alankoh

vmware服务可以改为手动，下载宋版的Vmware服务批处理可以设置手动启动虚拟机的服务。新建一个TXT文件，将以下批处理命令复制（不包括分隔线），保存为*.bat。
--------------------------------------------------------------------------------------------------------分隔线
@echo off
title VMware服务控制程序
color 5f
cls
echo.
echo.
echo A——设置VMware服务启动方式为自动
echo.
echo S——启动VMware服务
echo.
echo M——设置VMware服务启动方式为手动
echo.
echo T——停止VMware服务
echo.
echo K——暂时关闭VMWare的托盘图标
echo.
echo D——禁止VMWare自动启动托盘图标程序
echo.
echo 　　　　　　　　　　　　　　小宋制作
echo 　　　欢迎访问卡饭论坛：bbs.kafan.cn
echo.
SET t=
SET /P t=请选择（A/S/M/T/K/D）:
IF /I '%t:~0,1%'=='a' GOTO auto
IF /I '%t:~0,1%'=='s' GOTO start
IF /I '%t:~0,1%'=='m' GOTO demand
IF /I '%t:~0,1%'=='t' GOTO stop
IF /I '%t:~0,1%'=='k' GOTO killtray
IF /I '%t:~0,1%'=='d' GOTO deltray
exit

:auto
cls&&echo 正在修改服务启动方式为自动，请稍候...
sc config VMAuthdService start= auto>nul
sc config VMnetDHCP start= auto>nul
sc config "VMware NAT Service" start= auto>nul
echo 全部VMware服务已经更改为自动。

goto finish

:start
cls&&echo 正在启动服务，请稍候...
net start VMAuthdService>nul
net start VMnetDHCP>nul
net start "VMware NAT Service">nul
echo VMware服务启动完毕。

goto finish

:stop
cls&&echo 正在停止服务，请稍候...
net stop VMAuthdService>nul
net stop VMnetDHCP>nul
net stop "VMware NAT Service">nul
echo VMware服务已经全部停止。
goto finish

:demand
cls&&echo 正在修改服务启动方式为手动，请稍候...
sc config VMAuthdService start= demand>nul
sc config VMnetDHCP start= demand>nul
sc config "VMware NAT Service" start= demand>nul
echo 全部VMware服务已经更改为手动启动。
goto finish

:killtray
taskkill /f /im:"vmware-tray.exe"
echo 已经成功的关闭了VMWare的托盘图标。
echo 如需重新打开，请手动运行或重启计算机。
goto finish

:deltray
echo 该操作不可恢复，确定继续吗？
echo 按任意键继续，用鼠标点击右上角的“X”取消本操作。&pause>nul
reg delete HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /v vmware-tray /f
echo 成功的删除了VMWare的托盘图标启动项。
goto finish

:finish
echo.&&echo.&&echo.
echo 操作成功，按任意键退出。
echo.
echo 　　　　　　　　　　　　　　By 小宋
pause>nul&&exit
-----------------------------------------------------------------------------------------------------------分隔线

zzt323

那个  vmware virtual mount manager extended  服务是干什么的，除了以上提到三项服务，这个服务可以改手动吗

zhaonan007007

这些服务都可以设置为手动 只是在虚拟机中上网时要打开对应的服务
关闭服务对虚拟机的打开运行什么的没有影响

Beloved

偶的是自己动手改为手动的

启动VMware的时候，手动的自然启动