DOS批处理一站式修复IE首页（适用于注册表、快捷方式篡改法）

xp163

【转帖】 DOS批处理一站式修复IE首页（适用于注册表、快捷方式篡改法）
     2011-02-21 19:44
  原文链接：http://hi.baidu.com/%B1%A6%C8%F0%D3%A2/blog/item/83b2e4fbc64209d5b48f31a0.html
  修复原理见：http://hi.baidu.com/%B1%A6%C8%F0%D3%A2/blog/item/adbfa9509ca9fc10377abe3a.html
  注：代码中的符号★需要首先替换成Tab键，然后才能正常运行。

@echo off
title %~n0 by 宝瑞英 for %username%
echo.&echo                                 【程序说明】&echo.
echo    作者：宝瑞英 2010-3-13   http://hi.baidu.com/宝瑞英/
echo.&echo    说明：
echo          本程序运行后，将会把桌面上的URL快捷方式、文件名含Internet字符的
echo          lnk快捷方式、快速启动栏中IE图标、注册表中的恶意篡改项进行清除，
echo          清除上述各项之前，将会对各项进行备份。请用户知悉！&echo.
echo    鸣谢：“清河流动”提供部分原理及案例！&echo.
echo                                         按任意键开始修复...
pause>nul
cls&echo.&echo                              正在修复，请稍后...&echo.&echo.
setlocal enabledelayedexpansion
set pp="HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel"
reg add %pp% /v "Home Page" /t REG_DWORD /d 0 /f >nul
set pp="HKCU\Software\Microsoft\Internet Explorer\Main"
reg add %pp% /v "Start Page" /t REG_SZ /d about:blank /f >nul
set pp="HKLM\SOFTWARE\Classes\CLSID\{871C5380-42A0-1069-A2EA-08002B30309D}\shell\OpenHomePage\Command"
reg add %pp% /ve /t REG_SZ /d """"C:\Program Files\Internet Explorer\iexplore.exe"""" /f >nul
set pp="HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
for /f "skip=3 tokens=3 delims=★" %%a in ('reg query %pp% /v Desktop') do (
pushd %%a
)
set count_lnk=0
set maybe=%cd%\嫌疑项
if not exist "%maybe%" md "%maybe%"
call :search *Internet*.lnk
call :search *.url
popd
set pp="HKLM\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
for /f "skip=3 tokens=3 delims=★" %%a in ('reg query %pp% /v "Common Desktop"') do (
pushd %%a
)
call :search *Internet*.lnk
call :search *.url
popd
set quickie="C:\Documents and Settings\%USERNAME%\Application Data\Microsoft\Internet Explorer\Quick Launch\*Internet*.lnk"
if not exist %quickie% goto :next
copy %quickie% "%maybe%\" >nul
del %quickie% >nul
set /a count_lnk+=1
:next
if not !count_lnk!==0 echo 发现 !count_lnk! 个嫌疑链接文件！已备份至“嫌疑项”文件夹。
set count_reg=0
set pp=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Desktop\NameSpace
for /f "skip=5 tokens=2 delims={}" %%a in ('reg query %pp% /s') do (
set id={%%a}
call :chkclsid
)
if not !count_reg!==0 echo 发现 !count_reg! 个嫌疑注册表项！已备份至桌面“嫌疑项”文件夹。
set pp=HKCR\CLSID\{871C5380-42A0-1069-A2EA-08002B30309D}
reg delete %pp% /f >nul
reg add %pp% /v InfoTip /t REG_SZ /d "@C:\WINDOWS\system32\ieframe.dll.mui,-881" /f >nul
reg add %pp% /v LocalizedString /t REG_SZ /d "@C:\WINDOWS\system32\ieframe.dll.mui,-880" /f >nul
reg add %pp%\DefaultIcon /ve /t REG_SZ /d "C:\WINDOWS\system32\ieframe.dll,-190" /f >nul
reg add %pp%\InProcServer32 /ve /t REG_SZ /d "C:\WINDOWS\system32\ieframe.dll" /f >nul
reg add %pp%\InProcServer32 /v ThreadingModel /t REG_SZ /d Apartment /f >nul
reg add %pp%\shell /ve /t REG_SZ /d OpenHomePage /f >nul
reg add %pp%\shell\OpenHomePage /ve /t REG_SZ /d 打开主页(^&H) /f >nul
reg add %pp%\shell\OpenHomePage /v LegacyDisable /t REG_SZ /f >nul
reg add %pp%\shell\OpenHomePage /v MUIVerb /t REG_SZ /d "@shdoclc.dll,-10241" /f >nul
reg add %pp%\shell\OpenHomePage\Command /ve /t REG_SZ /d """"C:\Program Files\Internet Explorer\iexplore.exe"""" /f >nul
reg add %pp%\Shellex\ContextMenuHandlers\ieframe /ve /t REG_SZ /d {871C5380-42A0-1069-A2EA-08002B30309D} /f >nul
reg add %pp%\Shellex\MayChangeDefaultMenu /ve /t REG_SZ /d "" /f >nul
reg add %pp%\Shellex\PropertySheetHandlers\{871C5380-42A0-1069-A2EA-08002B30309D} /f >nul
reg add %pp%\ShellFolder /ve /t REG_SZ /d "C:\WINDOWS\system32\ieframe.dll,-190" /f >nul
reg add %pp%\ShellFolder /v Attributes /t REG_DWORD /d 36 /f >nul
reg add %pp%\ShellFolder /v HideAsDeletePerUser /t REG_SZ /f >nul
reg add %pp%\ShellFolder /v HideFolderVerbs /t REG_SZ /f >nul
reg add %pp%\ShellFolder /v HideOnDesktopPerUser /t REG_SZ /f >nul
reg add %pp%\ShellFolder /v WantsParseDisplayName /t REG_SZ /f >nul
echo.&echo.&echo 修复完成！请在桌面上右键刷新以使修改生效！&echo.
pause
exit

:search
for /f "delims=" %%a in ('dir /b %1 2^>nul') do (
copy "%%a" "%maybe%\" >nul
del "%%a" >nul
set /a count_lnk+=1
)
goto :eof
:chkclsid
for /f "skip=3 tokens=3 delims=★" %%a in ('reg query HKCR\CLSID\!id!\shell /s 2^>nul') do (
if not "%%a"=="" call :filter %%a
)
goto :eof
:filter
if /i not "%~nx1"=="iexplore.exe" goto :eof
reg export %pp%\!id! "%maybe%\!id!1.reg" >nul
reg delete %pp%\!id! /f >nul
reg export HKCR\CLSID\!id! "%maybe%\!id!2.reg" >nul
reg delete HKCR\CLSID\!id! /f >nul
set /a count_reg+=1
goto :eof

原文链接：http://hi.baidu.com/%B1%A6%C8%F0%D3%A2/blog/item/83b2e4fbc64209d5b48f31a0.html

我叫MT

这未免也太麻烦了吧，不过方法可以